法师：
冰法：
1.4层冰刺音效提示冰箭宏：
- 功能：按下则检测身上是否有4层冰刺buff，如果成立则播放释放冰甲术的声音
- 取消冰箱、下马，宠物调为辅助模式，如果当前没有选中敌对目标则选中一个随机的敌对目标，按下组合键则水元素释放水流喷射，释放寒冰箭
/run for i=1,40 do local B,_,_,C=UnitBuff("player",i); if (B=="冰刺" and C==4) then PlaySoundKitID(1456) end end
/cancelAura 寒冰屏障
/dismount
/petassist
/targetenemy [noharm]
/use [mod:alt]水流喷射
/use 寒冰箭
*4秒最多触发一次提示音
2.隐身术 宠物控制
- 隐身后控制水元素是很好的欺骗敌人的手段
- 功能：没有组合键时释放隐形术
- 按下alt组合键则命令宠物攻击并移动到指定地点
/use [nomod]隐形术
/petattack [mod:alt]
/petmoveto [mod:alt]
3.变形术 宠物跟随宏
- 功能：没有组合键时选择一个目标并释放变形术，按下组合键则将宠物设置成被动并跟随
/targetenemy [noharm,nomod]
/use [nomod]变形术
/petpassive [mod]
/petfollow [mod]
4.水元素一键宏
- 水元素的一键操作
- 功能：显示水元素的图标和CD
- 按下组合键则将水元素移动到指定位置
- 没有水元素时召唤水元素，否则释放水元素的冰冻术，同时下马
#show 召唤水元素
/petmoveto [pet,mod]
/use [nopet,nomounted] [@pet,dead] 召唤水元素
/use [nomod,pet]冰冻术
/dismount
- 去掉第一行则可以监视水元素或者冰冻术的CD(取决于是否有宠物存在)
5.冰风暴宏
- 冰风暴在该版本代替了霜火箭，拥有比寒冰箭更高的伤害，在通过脑部冻结顺发释放后还对目标施加1秒的深冬效果(判定是冰冻目标)
- 功能：连续释放冰风暴、冰枪术和寒冰箭三个技能，不按技能图标5秒后重置施法队列
/castsequence reset=5 冰风暴,冰枪术,寒冰箭
- 冰风暴在某些情况下可以代替冰箭作为水元素冰枪二连的读条技能，在使用瞬发的冰风暴后立刻接上一个冰枪以利用深冬效果
6.寒冰新星/冰冻之触接冰枪宏
- 避免没有目标、目标死亡时浪费寒冰新星，并将冰冻之触接冰枪整合进来
- 功能：
- 如果选择了寒冰新星天赋技能：
- 按下组合键时则对玩家使用寒冰新星，此外在有目标的时候对目标使用寒冰新星接一个冰枪术，不按宏2秒后重置队列
- 如果目标是友军，则对友军释放寒冰新星，并选择其当前目标
- 如果选择了冰冻之触技能：
- 对目标使用冰冻之触和两个冰枪，不按宏2秒后重置队列
/run local G=GetSpellInfo SetMacroSpell("宏的名字", G("寒冰新星") or "冰封之触")
/castsequence [harm] reset=2 冰冻之触,冰枪术,冰枪术
/castsequence [mod@player][exists,nodead] reset=2 寒冰新星,冰枪术
/tar [help]targettarget
7.变羊宏：
#showtooltip 变形术(乌龟)
/cast 变形术(乌龟)
/petpassive
8.焦点反制宏：
#showtooltip
/cast [target=focus] 法术反制
9.一键爆发宏：
- 功能：显示冰脉的图标、在有敌对目标时使用技能和道具，并读条主力输出技能
#show 冰冷血脉
/use [harm,nomod]按下组合键不放的技能
/use [mod]按下组合键时才放的技能/物品名称
/use [harm]冰冷血脉
/use [harm]咖啡压榨机
/use [harm]13
/use [harm]14
/use 寒冰箭
- 删除/use [harm]13和14一行则可以取消使用上格、下格饰品的功能
火法：
1.实用宏：
#showtooltip [talent:7/2]燃烬风暴; [talent:7/3]流星
/cast [nomod,@cursor][]流星
/cast [nomod,@cursor][]燃烬风暴
2.火冲宏：
#show 火焰冲击
/castsequence [nomod] reset=1 火焰冲击,炎爆术
/castsequence [mod] reset=1 火焰冲击,火焰冲击,炎爆术
3.燃烧爆发宏：
- 功能：显示燃烧的图标，按下后按照能量符文-燃烧-炎爆术-灼烧-流星-火焰冲击-烈焰飞舞-炎爆术-火焰冲击-炎爆术-火焰冲击-炎爆术的顺序释放技能，不按宏3秒后重置
#show 燃烧
/castsequence reset=3 能量符文,燃烧,炎爆术,灼烧,流星,炎爆术,火焰冲击,烈焰飞舞,炎爆术,火焰冲击,炎爆术,火焰冲击,炎爆术
4.烈焰飞舞火冲炎爆宏
- 功能：在触发一层buff、没有火冲可用而烈焰飞舞可用时，连打则按照烈焰飞舞-火冲-炎爆的顺序释放技能，不按2秒后重置队列
/castsequence reset=2 烈焰飞舞,火焰冲击,炎爆术
5.冲击波宏
- 避免目标死亡后的技能浪费
- 功能：按下组合键则对自己释放冲击波，此外如果目标存在则对目标释放冲击波，如果目标是友军则另外还选中该友军的当前目标
/use [mod@player][exists,nodead]冲击波
/tar [help]targettarget
- 最后一行可以加入/targetenemy [noharm] 获得额外的在当前目标不是敌对的情况下选中一个随机的敌对目标的效果
奥法：
1.爆发宏：
/use [harm]13
/use [harm]14
/castsequence [harm] reset=5 能量符文,奥术强化,奥术冲击,奥术冲击,奥术冲击,奥术冲击
- 可以插入多个使用消耗品的语句，直接套用/use [harm]13(使用上格饰品)即可
2.气定奥冲宏
/castsequence [harm] reset=2 气定神闲,奥术冲击,奥术冲击
3.超级新星/精力充沛一键宏
- 前面冰法对应宏的奥法版本，避免没有目标、目标死亡时浪费超级新星，并将精力充沛接奥冲整合进来
- 功能：
- 如果选择了超级新星天赋技能：
- 按下组合键时则对玩家使用超级新星，如果目标是友军，则对友军释放该技能，并选择其当前目标
- 如果选择了精力充沛技能：对目标使用精力充沛接奥术冲击，不按宏2秒后重置队列
/run local G=GetSpellInfo SetMacroSpell("宏的名字", G("精力充沛") or "超级新星")
/castsequence [harm] reset=2 精力充沛,奥术冲击
/use [mod@player][exists,nodead]超级新星
/tar [help]targettarget
4.闪现位移一键宏
/castsequence reset=10 闪现术,位移术
- 可以根据PvP天赋更改10这个数字，可以在第一行加入#show [mod]位移;闪现术 来显示闪现术的CD并在按下组合键时显示位移的CD，但依然推荐使用另外的图标分别监视2个技能的CD
通用宏：
1.鼠标位置/自身位置施法宏：
- 对于很多职业而言是巨大buff，不过能减少点击次数总是好的
- 功能：直接按下在鼠标指向位置释放烈焰风暴，按下shift的同时则在玩家本体位置释放，按下alt/ctrl则像原来那样瞄准后点击释放
/use [mod:shift,@player][nomod,@cursor][]烈焰风暴
- 烈焰风暴 改为流星暴风雪乃至工程手雷等圈圈范围技能均可达到类似效果
- 功能：施法队列中，逐个使用技能，在使用需要选定目标位置的技能时，按下shift的同时则在玩家本体位置释放，按下alt/ctrl则像原来那样瞄准后点击释放，否则对鼠标指向位置释放。不按宏2秒重置队列
/castsequence [mod:shift,@player][nomod,@cursor][] reset=2 技能名称1,技能名称2,技能名称3
2.主力输出技能宏
- 多功能合一、迅速转火外加偷懒效果
- 功能：取消冰箱并且下马
- 按下shift则选择集火目标，否则按下alt选择指定队友的目标，之后如果还没有选取敌对目标，则随机选取一个面前的敌对目标
- 命令宠物进入协助模式并攻击当前目标
- 按下组合键(alt/shift/ctrl)释放水元素的水流喷射
- 对当前选择的目标释放寒冰箭
/cancelAura 寒冰屏障
/dismount
/tar [mod:alt]指定队友名字
/assist [help]
/tar [mod:shift]优先集火目标名称
/targetenemy [noharm]
/petassist
/petattack
/use [mod:alt]水流喷射
/use [spec:3]寒冰箭;[spec:2]火球术;[spec:1]奥术冲击
- 替换寒冰箭即可在其他专精使用，使用前将指定队友名字改成你们团里转火手最快的那位的名字就好了
3.缓落术 功能坐骑 滑翔翼一键宏
- 功能：按下组合键对自己释放缓落术，按下shift键还使用披风(滑翔翼工程学附魔)，对鼠标指向的友军目标释放缓落术，在地面上则尝试使用功能坐骑(例如牦牛)
/use [mod,@player] [@mouseover,help] []缓落术
/use [mod:shift]15
/use 功能坐骑名称
4.目标焦点、焦点变形术宏
- 功能：图标显示变形术对于焦点目标的可用性(超出射程则显示为红色图标)
- 按下组合键将当前目标设置为焦点，如果没有当前目标则清除焦点
- 对焦点敌对目标释放变形术
#showtooltips [@focus] 变形术
/focus [@focus,noharm] [mod]
/clearfocus [@focus,dead]
/use [@focus,exists,harm] 变形术
5.造餐术 使用食物 就坐宏
- 功能：按下shift则释放造餐术，按下其他组合键则吃魔法布丁，什么都不按仅仅是原地 就坐
/use [mod:shift]造餐术;[mod:alt]魔法布丁;[mod]魔法布丁
/stopmacro [mod]
/sit
- 修改[mod:alt]魔法布丁处的道具名称可以添加“按下alt键使用其他技能/道具”的效果
6.互换焦点和当前目标
/tar [@focus]
/targetlasttarget
/focus
/targetlasttarget
/use 火球术
武僧：
酒仙：
1.一键宏：
#showtooltip
/targetenemy [dead][noharm]
/castsequence reset=combat 醉酿投,铁骨酒,火焰之息,幻灭猛击,猛虎掌,猛虎掌,幻灭猛击,魂体双分,醉酿投,铁骨酒,幻灭猛击,猛虎掌,猛虎掌,幻灭猛击,猛虎掌,幻灭猛击
2.使用modofier命令实现群嘲
#showtooltip 嚎镇八方
/tar [mod:shift] 玄牛雕像
/cast 嚎镇八方
/targetlasttarget [mod:shift]
- 效果是直接使用宏嘲讽当前目标，按住shift(你可以自己更改宏里面的shift来改变你想要按住的按键)来嘲讽雕像以实现群嘲。
3.取消雕像宏
/click TotemFrameTotem1 RightButton
织雾：
1.随机铺雾宏：
#showtooltips
/cancelaura 神鹤引项踢
/targetraid [group]
## 在团队中才使用随机功能，solo或者小队状态无效。
/cast [@mouseover,help] [help,nodead][@player] 复苏之雾
## 按照鼠标指向》目标》自己 的顺序释放复苏
/targetlasttarget [group]
/startattack [harm]
/script UIErrorsFrame:Clear()
## 屏蔽错误提示
##说是随机铺雾，其实是选中离你最近的一个人，如果全团位置没有变化，它每次都会选中同一个人。
2.防打断精华之泉的旭日宏：
#showtooltip
/stopmacro [channeling: 精华之泉]
/cast 旭日东升踢
这个宏能让你能够在不打断精华之泉且GCD允许的情况下，使用旭日东升踢
3.鼠标指向治疗 伤害技能整合：
#showtooltip
/use [@mouseover,help,nodead][help,nodead] 抚慰之雾;[harm] 猛虎掌;抚慰之雾
#showtooltip
/use [@mouseover,help,nodead][help,nodead] 复苏之雾;[harm] 幻灭踢;复苏之雾
#showtooltip
/use [@mouseover,help,nodead][help,nodead] 活血术;[harm] 旭日东升踢;活血术
#showtooltip
/use [@mouseover,help,nodead][help,nodead] 氤氲之雾;[harm] 神鹤引项踢;氤氲之雾
4.毛线切目标宏：
#showtooltip
/use [@mouseover,help,nodead][help,nodead] 抚慰之雾;[harm] 猛虎掌;抚慰之雾
/tar[@mouseover,help,nodead]
5.驱散 救人整合(鼠标指向盟友时驱散，脱战时如果在小队中使用群活，脱战时指向目标死亡使用单救)：
#showtooltip
/cast [@mouseover,help,nodead] 清创生血;[spec:2,group:party,nocombat] 死而复生;[@mouseover,help,dead,nocombat][help,dead,nocombat] 轮回转世;清创生血
6.智能施法雕像：
/cast [@cursor] 青龙雕像
7.氤氲宏：A 宏绿罩，平常是雷光 氤氲(瞬发)，带鼠标指向
#showtooltip [mod:alt]作茧缚命;氤氲之雾
/tar [@mouseover,help,nodead]
/cast [mod:alt]作茧缚命;氤氲之雾
/focus [@targettarget,harm,nodead]
8.贯通宏：A 宏绿罩，平常是贯通，带鼠标指向
#showtooltip [mod:alt]作茧缚命;真气贯通
/tar [@mouseover,help,nodead]
/cast [mod:alt]作茧缚命;真气贯通
/focus [@targettarget,harm,nodead]
9.复苏宏：带鼠标指向，如果点出禅意波，按第一下是复苏，第二下是禅意波，5秒不按就重置，没点禅意波就单纯是复苏
#showtooltip 复苏之雾
/stopmacro [channeling:精华之泉]
/tar [@mouseover,help,nodead]
/cast 雷光聚神茶
/castsequence [talent:1/2]reset=5/target 复苏之雾,禅意波,X;复苏之雾
/focus [@targettarget,harm,nodead]
10.赤精宏：有点真气爆裂就第一下真气爆裂，第二下赤精之歌，没有就单纯是赤精之歌
/castsequence [talent:1/1]reset=5 真气爆裂,赤精之歌
/cast 赤精之歌
11.精华宏：平常是活血术，A 宏是精华，假如天赋点出碧玉疾风，(那么必然有法力茶吧)A 宏就是雷光 法力茶 碧玉疾风，第二下A 宏是可移动(雷光强化)精华
#showtooltip [mod:alt]精华之泉;活血术
/cast [mod:alt]雷光聚神茶
/cast [mod:alt]法力茶
/stopmacro [channeling:精华之泉]
/castsequence [talent:6/1,mod:alt]reset=3 碧玉疾风,精华之泉;[mod:alt]精华之泉; [@targettarget,help] []活血术
踏风：
1.爆发宏 相对于一般水平的踏风来说简单实用：
/cast 轮回之触
/cast 白虎下凡
/cast 豪能酒
/cast 风火雷电
2.爆发宏2：
#showtooltip
/startattack
/castsequence [nochanneling] reset=10 猛虎掌,轮回之触,风火雷电,旭日东升踢,豪能酒,风领主之击,怒雷破,升龙霸,幻灭踢
3.爆发宏3：
/cleartarget
/targetenemy
/castsequence [nochanneling] reset=8 风火雷电,猛虎掌,真气波,猛虎掌,幻灭踢,猛虎掌,神鹤引项踢,猛虎掌,神鹤引项踢,怒雷破,豪能酒,神鹤引项踢,猛虎掌,神鹤引项踢,猛虎掌,神鹤引项踢,猛虎掌,幻灭踢,猛虎掌,神鹤引项踢,猛虎掌,旭日东升踢,升龙霸,猛虎掌
恶魔猎手
1、恶魔之咬/邪能之刃切换宏:
/cast [talent:2/1]恶魔之咬;[talent:2/2]邪能之刃;[talent:2/3]恶魔之咬
- 说明：第二层天赋点邪能之刃时显示该技能，否则显示恶魔之咬。通常用于邪刃和魔化天赋切换时用。
2、邪能爆发/涅墨西斯切换宏:
#showtooltip [talent:5/2]邪能爆发;[talent:5/3]涅墨西斯
/cast [talent:5/2]邪能爆发;[talent:5/3]涅墨西斯
- 说明：和上面那个宏原理一样，邪能爆发和涅墨西斯切换。
3、邪能毁灭/幽魂炸弹宏:
#showtooltip [nomod,talent:6/1]邪能毁灭;[nomod,talent:6/3]幽魂炸弹
/cast [nomod,talent:6/1]邪能毁灭;[nomod,talent:6/3]幽魂炸弹
4.投掷利刃宏:
#showtooltip
/cast [mod:shift,@focus] [@mouseover,harm] [nomod,@target]投掷利刃;投掷利刃
- 说明：有焦点的情况并按下SHIFT(可将宏里的SHIFT改成CTRL或者ALT)优先对焦点释放投掷利刃，其次对鼠标指向释放，最后对当前目标释放。可以将投掷利刃技能改成禁锢或魔法吞噬等技能效果一样。
5.鼠标指向地狱火撞击宏:
#showtooltip
/cast [@cursor] 地狱火撞击
- 说明：该宏不会出现绿色的指向圈图案，鼠标移动到哪里按下该宏后直接对着鼠标指向的地方用地狱火撞击，不需要再点一次鼠标。可以将地狱火撞击技能改成烈焰咒符或者沉默咒符等技能效果一样。
6.恶魔变形 自带音效宏:
/cast [nomod,@cursor]恶魔变形;[mod,@player]恶魔变形
/run local f=RbA or CreateFrame("Frame","RbA") f:SetScript("OnEvent",function(s,e,u,p) if u=="player" and p=="恶魔变形" then PlaySoundFile("SOUND\\午时已到.mp3") end end) f:RegisterEvent("UNIT_SPELLCAST_SUCCEEDED")
7.复杂的上马宏
/cancelaura 幽灵视觉
/use [nocombat]秘魔刃豹
/dismount [mounted]
/cast 滑翔
/cast [mod]疾影
/stopmacro [nocombat][channeling]
/target [@mouseover,harm]
/cast [@mouseover,harm] []邪能之刃
/stopmacro [@mouseover,noharm] [mod]
/targetlasttarget
/focus target
/targetlasttarget
- 功能解释：
- 不在战斗则召唤坐骑，在战斗则使用[邪能之刃]
- 如果战斗中鼠标指向了一个敌对目标，则切换该目标施放[邪能之刃]，并且把当前的目标设置为焦点
- 如果按下alt/shift/ctrl，则施放[疾影](不管在不在战斗状态)
- 如果在天上就滑翔
- 取消[幽灵视觉]回到正常移速
- 运用场景：
- 你正开心的打着怪，突然来了优先级更高的add，或者敌对玩家，你只需按一个键，就可以跳到这个目标身边，并同时把当前正在打的目标设置成焦点。
- 然后就是上/下马，空中飞一飞， 开个闪避 之类的
- 使用该宏需要注意的问题：
- 1.快捷键不要冲突，假设这个宏的快捷键是E,那[alt E]，[shift E]，[ctrl E]别设置成快捷键，不然会使施放[疾影]的语句失效
- 2.注意与鼠标指向目标的距离，如果超出距离，则无法使用[邪能之刃]
- 3.注意GCD，在技能转GCD的时候忍着别按
- 下面是逐行注解，抛砖引玉，大家可以按自己习惯DIY
- /cancelaura 幽灵视觉 ——如果有幽灵视觉则取消，吐槽一下，幽灵视觉的移动速度太慢了
- /use [nocombat]秘魔刃豹 ——如果不在战斗，使用坐骑，我氪了基佬紫的这个豹， 感觉还挺好看的 ，这里换坐骑可以先打开坐骑的界面，在/use 语句后面按住shift点击你想用的坐骑
- /dismount [mounted] ——如果在马上，就下马
- /cast 滑翔 ——如果在天上，就[滑翔]，这里的滑翔按第二下会取消，手速太快的可以写成 /cast !滑翔，这样滑翔就不会取消了
- /cast [mod]疾影 ——如果同时按下alt/shift/ctrl，释放[疾影]
- /stopmacro [nocombat][channeling] ——如果不在战斗状态，没使用任何通道类技能(如眼棱、弹幕)，则宏在这里停止，这句的目的是优先把眼棱弹幕打完再施放其他技能
- /target [@mouseover,harm] ——把鼠标指向(并且可以攻击的)目标设置为目标
- /cast [@mouseover,harm] []邪能之刃 ——向鼠标指向的(并且可以攻击的)目标释放[邪能之刃]，如果鼠标没有指向任何目标，则对当前目标使用[邪能之刃]
- /stopmacro [@mouseover,noexists] [mod] ——如果鼠标没有指向任何目标，或者在alt/shift/ctrl按下时，则宏在这里停止，这句的目的是为了在对当前目标进行[邪能之刃]时，不改变当前焦点(如果有的话)
- /targetlasttarget ——选择上一个目标(如果宏运行到这儿了，这里的lasttarget指的是add前你正在打的那个目标，你现在的目标已经是add了，我们选择add前这个目标)
- /focus target ——并把这个目标设置为焦点
- /targetlasttarget ——选择上一个目标(上一个目标指的是add，宏到这里完成了把add前的目标设置为焦点，并把add设置成当前目标)
8.焦点与目标互换宏
/cleartarget [@target,dead]
/clearfocus [@focus,dead]
/target [@focus,harm]
/cast 邪能之刃
/targetlasttarget
/focus target
/targetlasttarget
- 功能解释：
- 1.把当前目标设置为焦点
- 2.把当前焦点设置为目标
- 运用场景：
- 转火！转火！转火！
- 这里顺带说一下，因为DH的位移技能只有邪能之刃是目标指向的，才15码而且有GCD，所以效果并没有[暗影步][冲锋]好，如果你有战士或者DZ，本宏实用性会大大提高，值得拥有！
逐行注解：
- /cleartarget [@target,dead] ——如果目标死亡就清除目标(相当于点地板)
- /clearfocus [@focus,dead] ——如果焦点死亡就清除焦点
- /target [@focus,harm] ——把焦点设置为目标(如果有焦点而且焦点是敌对目标)
- /cast 邪能之刃
- /targetlasttarget ——选择上一个目标(这里指的是焦点变为目标前的那个目标)
- /focus target ——把这个目标设置为焦点
- /targetlasttarget ——选择上一个目标(也就是按下宏键前的焦点目标)
- 另外附上一个暗影步版加了鼠标指向的一键转火宏
- 比单纯的鼠标指向宏方便，因为目标跟着一起切换了，真正做到了一键
- 而且转火前的目标或成为新的焦点
- /clearfocus [@focus,dead]
- /cast [nostealth]!潜行
- /target [@mouseover,harm]
- /target [mod,@focus,harm]
- /cast 暗影步
- /stopmacro [@mouseover,noexists] [nomod]
- /targetlasttarget
- /focus target
- /targetlasttarget
9.保命宏：
#showtooltip 疾影
/施放 疾影
/CAST 幻影打击
后跳途中滑翔飞刀，用下你就懂了。
/cast 投掷利刃
/cast 滑翔
/startattack
死亡骑士：
冰DK：
1.龙喷防打断绑爆发饰品
#showtooltip
/use !冰龙吐息
/use 13
/charge
/y Anar'alah belore! 数字13是上面的饰品 放下面改成14
2.冰柱绑爆发饰品宏
/cast 冰霜之柱
/use 13
后面的数字如果你的双爆发饰品之前龙喷绑的是上面的饰品就把数字改成14绑下面的饰品
邪DK：
1.起手爆发宏：如果点了血肉之盾，最好把亡者复生这行去掉，改为手动亡者，否则BB一但死因为血肉之盾而死，就会卡宏
#showtooltip
/petattack
/castsequence reset=20/combat 爆发,脓疮打击,脓疮打击,亡者大军,黑暗仲裁者,凋零缠绕,寒冰锁链,黑暗突变,凋零缠绕
2.召唤 突变：
#showtooltip 亡者复生
/cast [nopet] 亡者复生; !黑暗突变
血DK：
1.窒息打断宏：
#showtooltips
/cast [@mouseover,harm][mod:alt]窒息;心灵冰冻
2.输出宏：
#showtooltip
/targetenemy [noharm][dead]
/castsequence reset=combat/10 死神的抚摩,血液沸腾,骨髓分裂,心脏打击,灵界打击,血液沸腾,骨髓分裂,心脏打击,灵界打击
/castsequence [combat] reset=2 活力分流,X
3.技能自动攻击绑定宏
功能：按下技能自动选取面前最近目标，易爆周有奇效
#showtooltip骨髓分裂
/ targetenemy [help] [dead] [noexists]
/ cast骨髓分裂
#showtooltip心脏打击
/ targetenemy [help] [dead] [noexists]
/ cast心脏打击
#showtooltip灵界打击
/ targetenemy [帮助] [死] [noexists]
/ cast灵界打击
4.指向/脚底凋零宏
功能：直接按下在鼠标指向位置释放凋零，按下shift的同时则在玩家本体位置释放，按下alt / ctrl则像原来那样瞄准后点击释放
/使用[mod：shift，@ player] [nomod ，@ cursor] []枯萎凋零
呼呼终于写完了，可算是累死小编了，这篇文章里的宏非常多，希望能够给大家带来哪怕是1%DPS的提升，小编也心满意足了。
,
